Последовательность чисел в Excel

Мы подготовили пошаговое руководство по работе с числовой последовательностью в Excel, которое подойдёт как для начинающих, так и для опытных пользователей. В этом руководстве вы узнаете, как создать последовательность чисел в Excel с помощью простых функций.

Простая арифметическая числовая последовательность

Самый простой способ создать последовательность чисел в Excel — использовать формулу ПОСЛЕД (SEQUENCE в английской версии). Подробную информацию об этой функции можно найти здесь: Функция последовательности в Excel.

Пример формулы для создания последовательности чисел в Excel из 10 чисел, начиная с 1 до 28 с шагом 3:

=ПОСЛЕД(10;1;1;3)

Если в вашей версии Excel отсутствует эта функция, вы можете использовать альтернативу с функцией СТРОКА:

=1+(СТРОКА(A1:A10)-1)*3

Функция СТРОКА(A1:A10) создает массив чисел 1, 2, 3, 4 и так далее до 10. Это определяет количество значений в числовой последовательности. Число 3 — это шаг, на который увеличивается каждое следующее число.

Формула возрастающей или убывающей последовательности случайных чисел

Чтобы сгенерировать возрастающую или убывающую последовательность случайных чисел, используйте функцию СЛУЧМЕЖДУ (RANDBETWEEN) для аргумента шага в формуле ПОСЛЕД.

Пример формулы для создания возрастающей последовательности случайных чисел в Excel с шагом от 1 до 10:

=ПОСЛЕД(B1; B2; B3; СЛУЧМЕЖДУ(1; 10))

Функция СЛУЧМЕЖДУ определяет случайный шаг в последовательности чисел в диапазоне от 1 до 10.

Для убывающей последовательности случайных чисел аргумент шага должен быть отрицательным. Добавьте знак минус перед функцией СЛУЧМЕЖДУ:

=ПОСЛЕД(B1; B2; B3; -СЛУЧМЕЖДУ(1; 10))

Примечание. Поскольку функция Excel СЛУЧМЕЖДУ является изменчивой, она будет генерировать новые случайные значения при каждом изменении любого значения на вашем рабочем листе. В результате ваша числовая последовательность будет постоянно меняться. Чтобы этого не произошло, вы можете использовать функцию Excel «Специальная вставка» > «Значения» , чтобы заменить формулы их значениями.

Как создать последовательность повторяющихся чисел

Иногда нужно создать последовательность, в которой каждое значение повторяется несколько раз.

Вот примеры формул для создания последовательности из 12 чисел с повторяющимися значениями. 

Каждое число в этой последовательности повторяется дважды. Вот примеры формул, в которых каждое значение в последовательности из 12 чисел повторяется дважды:

• =ОКРВВЕРХ(ПОСЛЕД(12;1;1;1)/2;1)
• =ОКРУГЛВВЕРХ(ПОСЛЕД(12;1;1;1)/2;0)
• =ОКРУГЛВВЕРХ(СТРОКА(A1:A12)/2;0)
• =ОТБР(ОСТАТ((СТРОКА(A1:A12)-1)/2;10)+1)
• =ROUNDUP(SEQUENCE(12,1,1,1)/2,0)
• =CEILING(SEQUENCE(12,1,1,1)/2,1)
• =ROUNDUP(ROW(A1:A12)/2,0)
• =TRUNC(MOD((ROW(A1:A12)-1)/2,10)+1)

Для другого количества повторений замените число 2 на нужное значение.

Кроме того, здесь вы можете заметить, что и здесь есть альтернатива функции ПОСЛЕД. То есть, последовательность можно создать без этой новой функции, если у вас старая версия Excel. Как ранее, для этого используем функцию СТРОКА.

Формула циклической последовательности

Предположим, нам нужна в Excel повторяющаяся числовая последовательность, например, 1, 2, 3, 1, 2, 3, 1, 2, 3, используйте любую из этих формул:

• =ОСТАТ(ПОСЛЕД(12;;0);3)+1
• =ОТБР(ОСТАТ((ПОСЛЕД(12;1;1;1)-1);3)+1)
• =ОСТАТ(СТРОКА(A1:A12)-1;3)+1
• =MOD(SEQUENCE(12,,0),3)+1 
• =TRUNC(MOD((SEQUENCE(12,1,1,1)-1)/1,3)+1)
• =MOD(ROW(A1:A12)-1,3)+1)

Число 3 в формулах указывает, сколько элементов должно быть в начальной последовательности чисел, которую вы будете циклично повторять. В нашем случае это три числа — 1, 2, 3.

Поскольку мы хотим получить последовательность из 12 чисел в нашем примере, вы можете в качестве альтернативы использовать СТРОКА(A1:A12) в третьей формуле.

Числовая последовательность в столбцах E и F демонстрирует, как можно циклично повторять значения в Excel.

• =ОТБР(ОСТАТ((ПОСЛЕД(12;1;1;1)-1)/2;3)+1)
• =ОСТАТ(ОКРУГЛВНИЗ((СТРОКА(A1:A12)-1)/2;0);3)+1
• =TRUNC(MOD((SEQUENCE(12,1,1,1)-1)/2,3)+1)
• =MOD(ROUNDDOWN((ROW(A1:A12)-1)/2,0),3)+1)

Надеюсь, эти примеры помогут вам создать необходимую последовательность чисел в Excel!

Вот ещё статьи по этой теме: